Tutorials/CraftTweaker

Mekanism has native support for CraftTweaker since version 1.12.1-9.4.1.

Requirements

  • Mekanism 9.4.1 or higher
  • MTLib

How does it work?

For almost every machine Mekanism adds there is a way to add recipes to it through CraftTweaker. One that doesn't have any custom recipes is the EnergizedSmelter, that uses the default Minecraft furnace recipes, which could also be added through CraftTweaker.

As an example says more than thousand words, you can find an example at the bottom of this page. Every part has the following layout:

Name of the machine
Which entry is what
An example to add a recipe
Which entry is what
An example to remove a recipe

Note that // is being used as comments in ZenScript files and things between [ ] are optional.

Example file

//Chemical Crystallizer
//InputGas, OutputStack
mods.mekanism.chemical.crystallizer.addRecipe(<gas:water>, <minecraft:ice>);
//OutputStack[, InputGas]
mods.mekanism.chemical.crystallizer.removeRecipe(<mekanism:otherdust:4>, <gas:lithium>);

//Chemical Dissolution Chamber
//InputStack, OutputGas
mods.mekanism.chemical.dissolution.addRecipe(<minecraft:ice>, <gas:water>);
//OutputGas[, InputStack]
mods.mekanism.chemical.dissolution.removeRecipe(<gas:osmium>, <mekanism:oreblock>);

//Chemical Infuser
//InputGas1, InputGas2, OutputGas
mods.mekanism.chemical.infuser.addRecipe(<gas:water>, <gas:deuterium>, <gas:chlorine>);
//OutputGas[, InputGas1, InputGas2]
mods.mekanism.chemical.infuser.removeRecipe(<gas:hydrogenchloride>, <gas:hydrogen>, <gas:chlorine>);

//Chemical Injection Chamber
//InputStack, InputGas, OutputStack
//InputGas only accepts "<gas:sulfuricAcid>", "<gas:water>" or "<gas:hydrogenChloride>"
mods.mekanism.chemical.injection.addRecipe(<minecraft:hardened_clay:1>, <gas:water>, <minecraft:clay>);
//OutputStack[, InputStack, InputGas]
mods.mekanism.chemical.injection.removeRecipe(<mekanism:shard:2>, <mekanism:oreblock>, <gas:hydrogenchloride>);

//Chemical Oxidizer
//InputStack, OutputGas
mods.mekanism.chemical.oxidizer.addRecipe(<mekanism:dust:2>, <gas:cleanOsmium>);
//OutputGas[, InputStack]
mods.mekanism.chemical.oxidizer.removeRecipe(<gas:brine>, <mekanism:salt>);

//Chemical Washer
//InputGas, OutputGas
mods.mekanism.chemical.washer.addRecipe(<gas:chlorine>, <gas:water>);
//OutputGas[, InputGas]
mods.mekanism.chemical.washer.removeRecipe(<gas:cleanLead>, <gas:lead>);

//Combiner
//InputStack, InputStack, OutputStack
mods.mekanism.combiner.addRecipe(<minecraft:stone> * 4, <minecraft:cobblestone>, <minecraft:stonebrick>);
//OutputStack[, InputStack, InputStack]
mods.mekanism.combiner.removeRecipe(<minecraft:gravel>, <minecraft:flint>, <minecraft:cobblestone>);

//Osmium Compressor
//InputStack, InputGas, OutputStack
mods.mekanism.compressor.addRecipe(<mekanism:basicblock:3>, <gas:liquidOsmium>, <minecraft:bedrock>);
//OutputStack[, InputStack, InputGas]
mods.mekanism.compressor.removeRecipe(<mekanism:ingot>, <mekanism:otherdust:5>, <gas:liquidOsmium>);

//Crusher
//InputStack, OutputStack
mods.mekanism.crusher.addRecipe(<minecraft:double_plant:4>, <minecraft:dye:1> * 5);
//OutputStack, InputStack
mods.mekanism.crusher.removeRecipe(<minecraft:sand>, <minecraft:gravel>);

//Energized Smelter
//InputStack, OutputStack
mods.mekanism.smelter.addRecipe(<minecraft:tallgrass:1>, <minecraft:deadbush>);
//InputStack[, OutputStack]
mods.mekanism.smelter.removeRecipe(<minecraft:sand>, <minecraft:glass>);

//Enrichment Chamber
//InputStack, OutputStack
mods.mekanism.enrichment.addRecipe(<minecraft:coal_block>, <mekanism:compressedcarbon> * 9);
//InputStack[, OutputStack]
mods.mekanism.enrichment.removeRecipe(<minecraft:mossy_cobblestone>, <minecraft:cobblestone>);

//Metallurgic Infuser
//InfusionString, InputInfusion, InputStack, OutputStack //InfusionString = CARBON;TIN;DIAMOND;REDSTONE;FUNGI;BIO;OBSIDIAN
mods.mekanism.infuser.addRecipe("OBSIDIAN", 20, <minecraft:coal_block>, <minecraft:obsidian>);
//OutputStack[, InputStack, InfusionString]
mods.mekanism.infuser.removeRecipe(<minecraft:mycelium>);

//Purification Chamber
//InputStack, InputGas, OutputStack
mods.mekanism.purification.addRecipe(<minecraft:wool:1>, <gas:hydrogenchloride>, <minecraft:wool>);
//OutputStack[, InputStack, InputGas]
mods.mekanism.purification.removeRecipe(<mekanism:clump:2>, <mekanism:shard:2>, <gas:oxygen>);

//Pressurised Reaction Chamber
//InputStack, InputFluid, InputGas, OutputStack, OutputGas, InputRF, Time in Ticks
mods.mekanism.reaction.addRecipe(<mekanism:polyethene>, <liquid:liquidethene>, <gas:oxygen>, <mekanism:polyethene> * 8, <gas:oxygen>, 50000, 2000);
//OutputStack[, OutputGas, InputStack, InputFluid, InputGas]
mods.mekanism.reaction.removeRecipe(<mekanism:substrate>, <gas:ethene>, <mekanism:biofuel>, <liquid:water>, <gas:hydrogen>);

//Precision Sawmill
//InputStack, OutputStack1, OutputStack2, Chance
mods.mekanism.sawmill.addRecipe(<minecraft:bow>, <minecraft:stick> * 3, <minecraft:string> * 3, 0.5);
//InputStack[, OutputStack1, OutputStack2]
mods.mekanism.sawmill.removeRecipe(<minecraft:bed>, <minecraft:planks>, <minecraft:wool>);

//Electrolytic Separator
//InputFluid, InputRF, OutputGas1, OutputGas2
mods.mekanism.separator.addRecipe(<liquid:liquidfusionfuel>, 5000, <gas:deuterium>, <gas:tritium>);
//InputFluid[, OutputGas1, OutputGas2]
mods.mekanism.separator.removeRecipe(<liquid:heavywater>, <gas:deuterium>, <gas:oxygen>);

//Solar Evaporation
//InputFluid, OutputFluid
mods.mekanism.thermalevaporation.addRecipe(<liquid:lava>, <liquid:liquidfusionfuel>);
//InputFluid[, OutputFluid]
mods.mekanism.thermalevaporation.removeRecipe(<liquid:water>, <liquid:brine>);

//Solar Neutron Activator
//InputGas, OutputGas
mods.mekanism.solarneutronactivator.addRecipe(<gas:liquidStone>, <gas:liquidOsmium>);
//InputGas[, OutputGas]
mods.mekanism.solarneutronactivator.removeRecipe(<gas:lithium>, <gas:tritium>);


Cookies help us deliver our services. By using our services, you agree to our use of cookies.

Need wiki hosting?

Do you need a wiki for your Minecraft mod/gaming wiki? We'll host it for free! Contact us.

Other wikis

Indie-game wikis
Powered by Indie Wikis